make PREFIX="${INSTALL_ROOT}/usr" install &&

# zstd's make build installs no CMake package files, so CMake projects
# that look for zstd with find_package (openimageio 3.2, for one) don't
# find it. Install the same package and targets zstd's own CMake build
# would: zstd::libzstd_shared, zstd::libzstd_static and zstd::libzstd
ZSTD_CMAKE="${INSTALL_ROOT}/usr/lib/cmake/zstd" &&
mkdir -p "$ZSTD_CMAKE" &&
cat > "$ZSTD_CMAKE/zstdConfig.cmake" <<'EOF' &&
# Written by the Source Mage zstd spell (zstd is built with make)
get_filename_component(_zstd_prefix "${CMAKE_CURRENT_LIST_DIR}/../../.." ABSOLUTE)
if(NOT TARGET zstd::libzstd_shared AND EXISTS "${_zstd_prefix}/lib/libzstd.so")
  add_library(zstd::libzstd_shared SHARED IMPORTED)
  set_target_properties(zstd::libzstd_shared PROPERTIES
    IMPORTED_LOCATION "${_zstd_prefix}/lib/libzstd.so"
    INTERFACE_INCLUDE_DIRECTORIES "${_zstd_prefix}/include")
endif()
if(NOT TARGET zstd::libzstd_static AND EXISTS "${_zstd_prefix}/lib/libzstd.a")
  add_library(zstd::libzstd_static STATIC IMPORTED)
  set_target_properties(zstd::libzstd_static PROPERTIES
    IMPORTED_LOCATION "${_zstd_prefix}/lib/libzstd.a"
    INTERFACE_INCLUDE_DIRECTORIES "${_zstd_prefix}/include")
endif()
if(NOT TARGET zstd::libzstd)
  add_library(zstd::libzstd INTERFACE IMPORTED)
  if(TARGET zstd::libzstd_shared)
    set_target_properties(zstd::libzstd PROPERTIES INTERFACE_LINK_LIBRARIES zstd::libzstd_shared)
  else()
    set_target_properties(zstd::libzstd PROPERTIES INTERFACE_LINK_LIBRARIES zstd::libzstd_static)
  endif()
endif()
unset(_zstd_prefix)
EOF
cat > "$ZSTD_CMAKE/zstdConfigVersion.cmake" <<EOF
set(PACKAGE_VERSION "${VERSION}")
if(PACKAGE_FIND_VERSION VERSION_GREATER PACKAGE_VERSION)
  set(PACKAGE_VERSION_COMPATIBLE FALSE)
else()
  set(PACKAGE_VERSION_COMPATIBLE TRUE)
  if(PACKAGE_FIND_VERSION STREQUAL PACKAGE_VERSION)
    set(PACKAGE_VERSION_EXACT TRUE)
  endif()
endif()
EOF
